From 092308792121db350cf9832613aaaf7ff914782f Mon Sep 17 00:00:00 2001
From: "Bryan A. S" <53131727+bryanasdev000@users.noreply.github.com>
Date: Fri, 20 May 2022 10:02:57 -0300
Subject: [PATCH] jira-cli-go: init at 0.3.0 (#173440)

Co-authored-by: Sandro <sandro.jaeckel@gmail.com>
---
 .../development/tools/jira-cli-go/default.nix | 44 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 +
 2 files changed, 46 insertions(+)
 create mode 100644 pkgs/development/tools/jira-cli-go/default.nix

diff --git a/pkgs/development/tools/jira-cli-go/default.nix b/pkgs/development/tools/jira-cli-go/default.nix
new file mode 100644
index 00000000000..75640ddf33f
--- /dev/null
+++ b/pkgs/development/tools/jira-cli-go/default.nix
@@ -0,0 +1,44 @@
+{ lib, buildGoModule, fetchFromGitHub, less, more, installShellFiles, testVersion, jira-cli-go }:
+
+buildGoModule rec {
+  pname = "jira-cli-go";
+  version = "0.3.0";
+
+  src = fetchFromGitHub {
+    owner = "ankitpokhrel";
+    repo = "jira-cli";
+    rev = "v${version}";
+    sha256 = "sha256-sPoFv3Gzue5H6TJuQZJvqB/Dx/URp9Kt2UuIvKSnAxg=";
+  };
+
+  vendorSha256 = "sha256-UO30/D65vpu3PgEsfSDL3nYgkwo5Cj+1WKiokk7KKKg=";
+
+  ldflags = [
+    "-s" "-w"
+    "-X github.com/ankitpokhrel/jira-cli/internal/version.GitCommit=${src.rev}"
+    "-X github.com/ankitpokhrel/jira-cli/internal/version.SourceDateEpoch=0"
+    "-X github.com/ankitpokhrel/jira-cli/internal/version.Version=${version}"
+  ];
+
+  checkInputs = [ less more ]; # Tests expect a pager in $PATH
+
+  passthru.tests.version = testVersion {
+    package = jira-cli-go;
+    command = "jira version";
+    inherit version;
+  };
+
+  nativeBuildInputs = [ installShellFiles ];
+  postInstall = ''
+    installShellCompletion --cmd jira \
+      --bash <($out/bin/jira completion bash) \
+      --zsh <($out/bin/jira completion zsh)
+  '';
+
+  meta = with lib; {
+    description = "Feature-rich interactive Jira command line";
+    homepage = "https://github.com/ankitpokhrel/jira-cli";
+    license = licenses.mit;
+    maintainers = with maintainers; [ bryanasdev000 ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 4b21823e53d..0eb2227eb7a 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -7277,6 +7277,8 @@ with pkgs;
 
   jira-cli = callPackage ../development/tools/jira_cli { };
 
+  jira-cli-go = callPackage ../development/tools/jira-cli-go { };
+
   jirafeau = callPackage ../servers/web-apps/jirafeau { };
 
   jitterentropy = callPackage ../development/libraries/jitterentropy { };