itktcl: init at 4.1.0

Signed-off-by: Austin Seipp <aseipp@pobox.com>

pkgs/development/libraries/itktcl/default.nix

@@ -0,0 +1,37 @@
+{ stdenv, fetchurl, tcl, tk, incrtcl }:
+
+stdenv.mkDerivation rec {
+  pname = "itk-tcl";
+  version = "4.1.0";
+
+  src = fetchurl {
+    url    = "mirror://sourceforge/incrtcl/%5BIncr%20Tcl_Tk%5D-source/3.4/itk${version}.tar.gz";
+    sha256 = "1iy964jfgsfnc1agk1w6bbm44x18ily8d4wmr7cc9z9f4acn2r6s";
+  };
+
+  buildInputs = [ tcl tk incrtcl ];
+  enableParallelBuilding = true;
+
+  configureFlags = [
+    "--with-tcl=${tcl}/lib"
+    "--with-tk=${tk}/lib"
+    "--with-tkinclude=${tk.dev}/include"
+    "--with-itcl=${incrtcl}/lib"
+  ];
+
+  postInstall = ''
+    rmdir $out/bin
+    mv $out/lib/itk${version}/* $out/lib
+    rmdir $out/lib/itk${version}
+  '';
+
+  outputs = [ "out" "dev" "man" ];
+
+  meta = with stdenv.lib; {
+    homepage    = "http://incrtcl.sourceforge.net/";
+    description = "Mega-widget toolkit for incr Tk";
+    license     = licenses.tcltk;
+    platforms   = platforms.unix;
+    maintainers = with maintainers; [ thoughtpolice ];
+  };
+}

pkgs/top-level/all-packages.nix

@@ -12054,6 +12054,7 @@ in
 
   ijs = callPackage ../development/libraries/ijs { };
 
+  itktcl  = callPackage ../development/libraries/itktcl { };
   incrtcl = callPackage ../development/libraries/incrtcl { };
 
   indicator-application-gtk2 = callPackage ../development/libraries/indicator-application/gtk2.nix { };