pythonPackages.pytesseract: init at 0.2.5

Simple python wrapper for Tesseract, an OCR engine to detect and read
text from images.

See https://pypi.org/project/pytesseract/

pkgs/development/python-modules/pytesseract/default.nix

@@ -0,0 +1,31 @@
+{ buildPythonPackage, fetchPypi, lib, pillow, tesseract, substituteAll }:
+
+buildPythonPackage rec {
+  pname = "pytesseract";
+  version = "0.2.5";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "0wlz1vbg1k8cdrpzvrahjnbsfs4ki6xqhbkv17ycfchh7h6kfkfm";
+  };
+
+  patches = [
+    (substituteAll {
+      src = ./tesseract-binary.patch;
+      drv = "${tesseract}";
+    })
+  ];
+
+  buildInputs = [ tesseract ];
+  propagatedBuildInputs = [ pillow ];
+
+  # the package doesn't have any tests.
+  doCheck = false;
+
+  meta = with lib; {
+    homepage = https://pypi.org/project/pytesseract/;
+    license = licenses.gpl3;
+    description = "A Python wrapper for Google Tesseract";
+    maintainers = with maintainers; [ ma27 ];
+  };
+}

pkgs/development/python-modules/pytesseract/tesseract-binary.patch

@@ -0,0 +1,13 @@
+diff --git a/src/pytesseract.py b/src/pytesseract.py
+index 32713cf..5f9209d 100755
+--- a/src/pytesseract.py
++++ b/src/pytesseract.py
+@@ -25,7 +25,7 @@ if numpy_installed:
+     from numpy import ndarray
+ 
+ # CHANGE THIS IF TESSERACT IS NOT IN YOUR PATH, OR IS NAMED DIFFERENTLY
+-tesseract_cmd = 'tesseract'
++tesseract_cmd = '@drv@/bin/tesseract'
+ RGB_MODE = 'RGB'
+ OSD_KEYS = {
+     'Page number': ('page_num', int),

pkgs/top-level/python-packages.nix

@@ -609,6 +609,8 @@ in {
 
   pystache = callPackage ../development/python-modules/pystache { };
 
+  pytesseract = callPackage ../development/python-modules/pytesseract { };
+
   pytest-tornado = callPackage ../development/python-modules/pytest-tornado { };
 
   python-binance = callPackage ../development/python-modules/python-binance { };