diff --git a/pkgs/applications/audio/miniaudicle/default.nix b/pkgs/applications/audio/miniaudicle/default.nix
new file mode 100644
index 00000000000..9c49f26bb4a
--- /dev/null
+++ b/pkgs/applications/audio/miniaudicle/default.nix
@@ -0,0 +1,59 @@
+{ lib
+, stdenv
+, fetchurl
+, bison
+, flex
+, which
+, alsaLib
+, libsndfile
+, qt4
+, qscintilla
+, libpulseaudio
+, libjack2
+, audioBackend ? "pulse" # "pulse", "alsa", or "jack"
+}:
+
+stdenv.mkDerivation rec {
+  pname = "miniaudicle";
+  version = "1.3.5.2";
+
+  src = fetchurl {
+    url = "https://audicle.cs.princeton.edu/mini/release/files/miniAudicle-${version}.tgz";
+    hash = "sha256-dakDz69uHbKZFj8z67CubmRXEQ5X6GuYqlCXXvLzqSI=";
+  };
+
+  sourceRoot = "miniAudicle-${version}/src";
+
+  postPatch = ''
+    substituteInPlace miniAudicle.pro \
+      --replace "/usr/local" $out
+  '';
+
+  nativeBuildInputs = [
+    bison
+    flex
+    which
+  ];
+
+  buildInputs = [
+    alsaLib
+    libsndfile
+    qt4
+    qscintilla
+  ] ++ lib.optional (audioBackend == "pulse") libpulseaudio
+    ++ lib.optional (audioBackend == "jack")  libjack2;
+
+  buildFlags = [ "linux-${audioBackend}" ];
+
+  makeFlags = [ "PREFIX=$(out)" ];
+
+  meta = with lib; {
+    description = "A light-weight integrated development environment for the ChucK digital audio programming language";
+    homepage = "https://audicle.cs.princeton.edu/mini/";
+    downloadPage = "https://audicle.cs.princeton.edu/mini/linux/";
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ fgaz ];
+    platforms = platforms.all;
+    broken = stdenv.isDarwin; # not attempted
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 8c4d82452e7..544d2f71825 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -24668,6 +24668,8 @@ in
 
   mikmod = callPackage ../applications/audio/mikmod { };
 
+  miniaudicle = callPackage ../applications/audio/miniaudicle { };
+
   minicom = callPackage ../tools/misc/minicom { };
 
   minimodem = callPackage ../applications/radio/minimodem { };