You can not select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
41 lines
1.4 KiB
41 lines
1.4 KiB
{ lib, buildLinux, fetchurl
|
|
, kernelPatches ? [ ]
|
|
, structuredExtraConfig ? {}
|
|
, extraMeta ? {}
|
|
, argsOverride ? {}
|
|
, ... } @ args:
|
|
|
|
let
|
|
version = "5.4.193-rt74"; # updated by ./update-rt.sh
|
|
branch = lib.versions.majorMinor version;
|
|
kversion = builtins.elemAt (lib.splitString "-" version) 0;
|
|
in buildLinux (args // {
|
|
inherit version;
|
|
|
|
src = fetchurl {
|
|
url = "mirror://kernel/linux/kernel/v5.x/linux-${kversion}.tar.xz";
|
|
sha256 = "187jfk9hf52n5z9yv56vq1knp3kdcbyk5w5k98ziwcbdjm1x65hd";
|
|
};
|
|
|
|
kernelPatches = let rt-patch = {
|
|
name = "rt";
|
|
patch = fetchurl {
|
|
url = "mirror://kernel/linux/kernel/projects/rt/${branch}/older/patch-${version}.patch.xz";
|
|
sha256 = "1gn4ii5pr0870ba481nqbd5rxk7ajrarv1p5mipfi42x07rpn7c2";
|
|
};
|
|
}; in [ rt-patch ] ++ kernelPatches;
|
|
|
|
structuredExtraConfig = with lib.kernel; {
|
|
PREEMPT_RT = yes;
|
|
# Fix error: unused option: PREEMPT_RT.
|
|
EXPERT = yes; # PREEMPT_RT depends on it (in kernel/Kconfig.preempt)
|
|
# Fix error: option not set correctly: PREEMPT_VOLUNTARY (wanted 'y', got 'n').
|
|
PREEMPT_VOLUNTARY = lib.mkForce no; # PREEMPT_RT deselects it.
|
|
# Fix error: unused option: RT_GROUP_SCHED.
|
|
RT_GROUP_SCHED = lib.mkForce (option no); # Removed by sched-disable-rt-group-sched-on-rt.patch.
|
|
} // structuredExtraConfig;
|
|
|
|
extraMeta = extraMeta // {
|
|
inherit branch;
|
|
};
|
|
} // argsOverride)
|
|
|